Difference between revisions of "Report DSL"

formatters {
    [ <FormatType> ]*
}

FormatType: <UomoFormat> | <NumberFormat> | <CurrencyFormat> | <DateFormat> | <DateTimeFormat> | <TimeFormat>

UomoFormat:	uomo <UomoID> {
		    ui "<UiPattern>" report "<ReportPattern>" textalign <TextAlign> 
		}

NumberFormat:	number <NumberID> { 
		    ui "<UiPattern>" report <NumberFormatCategory> "<ReportPattern>" textalign <TextAlign> 
		}

CurrencyFormat:	currency <CurrencyID> { 
		    ui "<UiPattern>" report <CurrencyFormatCategory> "<ReportPattern>" textalign <TextAlign> 
		}

DateFormat:	date <DateID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

DateTimeFormat:	date+time <DateAndTimeID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

TimeFormat:	time <TimeID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

UomoID: The identification name for the defined uomo format type.
NumberID: The identification name for the number format type.
CurrencyID: The identification name for the currency format type.
DateID: The identification name for the date format type.
DateAndTimeID: The identification name for the date and time format type.
TimeID: The identification name for the time format type.
UiPattern: A text that will be used as pattern for the visualization of the report (actually not used). 
ReportPattern: A text that will be used as format pattern for the corresponding style within the report. 
TextAlign: left | center | right
NumberFormatCategory: unformatted | general-number | fixed | percent | scientific | custom
CurrencyFormatCategory: unformatted | currency | custom

formatters {
	/** empty UOMO format */
	uomo uomo_test {
		ui "test"
		report "test"
		textalign left
	}
		
	/** money in EURO, rounding half-up */
	currency money_euro {
		ui "###,##0.00 €"
		report currency "#,##0.00 EUR{RoundingMode=HALF_UP}"
		textalign right
	}
		
	/** date without time with weekday */
	date+time shortdate {
		ui "SHORTDATE"
		report custom "dd.MM.yyyy"
		textalign left
	}
		
	/** integer */
	number integer {
		ui "##0"
		report percent "##0"
		textalign right
	}
		
	/** percent */
	number ^percent {
		ui "##0.0'%'"
		report percent "##0.0'%'"
		textalign right
	}
}

styles {
	/** if a currency has to be rendered */
	style ^currency { 
		formatter money_euro
	}
}

colors {
  [ color <ColorID> "<ColorString>" | <Darkens> | <Lightens> | <Transforms> ]*
}

ColorID: The identification name of the defined color.
ColorString: The hexadecimal color code.

Darkens: darkens <RefColorID> by-percent <Number>
Lightens: lightens <RefColorID> by-percent <Number>
Transforms: transforms <RefColorID> by-percent <Number> towards <RefColorID>

RefColorID: The reference to the previously defined color via its identification name.
Number: A number to define the value in percentage for darkens, lightens and transforms.

colors {
	/** the basic text color: BLACK */
	color black "#000000"
	/** grey rgb(128,128,128) */
	color grey_128 "#808080"
	/** grey rgb(136,136,136) */
	color grey_136 "#888888"
	/** grey rgb(220,220,220) */
	color grey_220 "#dcdcdc"
	/** grey rgb(235,235,235) */
	color grey_235 "#ebebeb"
	/** grey rgb(250,250,250) */
	color grey_250 "#fafafa"
	/** white */
	color white "#ffffff"
	/** light grey, according to the style guide rather rgb(244,252,255) but it is to weak on screen! */
	color lightgrey "#e4ecff"
	color red "#ff3b30"
	color orange "#ffcc00"
	color darkblue "#007aff"
	color grey_darkens darkens grey_136 by-percent 50
	color lightblack lightens black by-percent 30 
	color lightblue "#52edc7"
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
	}
}

fonts {
   [font <FontID> [extends <RefFontID> ] {
         [family <BuildInFontFamily> | "<CustomFontFamilyString>"] 
         [<FontStyle>] 
         [bold] 
         [size <UnsignedSizeNumber> <Unit>]
   }]*
}

FontID: The identification name for the defined font.
RefFontID: The reference to the previously defined font via its identification name.
BuildInFontFamily: monospace | sans-serif | serif
CustomFontFamilyString: A free available text that should be equal to an existing font family.
FontStyle: normal | italic | oblique
UnsignedSizeNumber: An unsigned number to define the the corresponding font size.
Unit: mm | cm | pt | inch | pc | em | ex | px | %

fonts {
	font arial_14pt_bold {
		family "Arial"
		bold
		size 14 pt
	}
		
	font arial_12pt_regular {
		family "Arial"
		normal
		size 12 pt
	}
		
	font arial_12pt_bold {
		family "Arial"
		bold
		size 12 pt
	}

	font arial_8pt_regular {
		family "Arial"
		normal
		size 8 pt
	}
			
	font arial_7pt_bold {
		family "Arial"
		bold
		size 7 pt
	}
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
	}
}

medias {
	[media <MediaID>]*
}

MediaID: The identification name of the defined media.

medias {
	/** Format for tabular reports e.g. for the use at the office */
	media middle
	/** Format for tabular reports e.g. for the use at the warehouse */
	media big
	/** Format for tabular reports e.g. for the use at the office and for the storage */
	media small
	/** Format for tabular reports as invoices, delivery orders, etc. */
	media ^report
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
		media big {font arial_12pt_regular}
	}
		
	/** header */
	style headerarea {
		extends bootstrap
		font arial_10pt_regular
		media big {font arial_12pt_regular}
		media small {font arial_8pt_regular}
	}
}

styles {
	[style <StyleID> {
		[extends <RefStyleID>]
		  [formatter <RefFormatterID>] 
		  [font <RefFontID>] 
		  [backgroundcolor <RefColorID> [alternate <RefColorID>]] 
		  [textcolor <RefColorID>] 
		  [textalign <TextAlign>] 
		  [verticalalign <VerticalTextAlign>] 
		  [border-top <BorderStyle>] 
		  [border-bottom <BorderStyle>] 
		  [border-left <BorderStyle>] 
		  [border-right <BorderStyle>] 
		  [padding-top <UnsignedNumber>] 
		  [padding-bottom <UnsignedNumber>] 
		  [padding-left <UnsignedNumber>] 
		  [padding-right <UnsignedNumber>] 
		  [margin-top <UnsignedNumber>] 
		  [margin-bottom <UnsignedNumber>] 
		  [margin-left <UnsignedNumber>] 
		  [margin-right <UnsignedNumber>] 
		[media <RefMediaID> {
			[formatter <RefFormatterID>]
			[font <RefFontID>]
			[backgroundcolor <RefColorID> [alternate <RefColorID>]]
			[textcolor <RefColorID>]
			[textalign <TextAlign>]
			[verticalalign <VerticalTextAlign>]
			[border-top <BorderStyle>]
			[border-bottom <BorderStyle>]
			[border-left <BorderStyle>]
			[border-right <BorderStyle>]
			[padding-top <UnsignedNumber>]
			[padding-bottom <UnsignedNumber>]
			[padding-left <UnsignedNumber>]
			[padding-right <UnsignedNumber>]
			[margin-top <UnsignedNumber>]
			[margin-bottom <UnsignedNumber>]
			[margin-left <UnsignedNumber>]
			[margin-right <UnsignedNumber>]
		}]*
	}]*
}

StyleID: The identification name for the defined style.
RefStyleID: The reference to the previously defined style via its identification name.
RefFormatterID: The reference to the previously defined formatter via its identification name.
RefFontID: The reference to the previously defined font via its identification name.
RefColorID: The reference to the previously defined color via its identification name.
TextAlign: left | center | right
VerticalTextAlign: bottom | middle | top
BorderStyle: <BorderType> <WidthNumber> <RefColorID>
BorderType: none | solid | dotted | dashed | double | groove | ridge | inset | outset
WidthNumber: Unsigned number to define the corresponding border width.
UnsignedNumber: Unsigned number to define the corresponding top, bottom, left and right padding or margin.

styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
		media big {
			font arial_12pt_regular
		}
	}
		
	/** Headline */
	style headline {
		extends bootstrap
		font arial_14pt_bold
	}
		
	/** Header */
	style headerarea {
		extends bootstrap
		font arial_10pt_regular
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** Table header */
	style tableheader {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_220
		border-top solid 1 black
		border-bottom solid 1 black
		border-left solid 1 grey_128
		border-right solid 1 grey_128
		media big {
			font arial_12pt_bold
		}
	}

	/** 1. header grouping level */
	style grouping_1_head {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_235
		border-top solid 1 black
		border-bottom solid 1 grey_136
		media big {
			font arial_12pt_bold
		}
		media small {
			font arial_8pt_bold
		}
	}

	/** 2. and more header grouping levels */
	style grouping_2_head {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_250
		border-top solid 1 grey_136
		media big {
			font arial_12pt_bold
		}
		media small {
			font arial_8pt_bold
		}
	}
		
	/** Standard line (lowest level) */
	style defaultrow {
		extends bootstrap
		font arial_8pt_regular
		backgroundcolor white alternate lightblue
		padding-left 2
		padding-right 2
		media big {
			font arial_12pt_regular
		}
	}
		
	/** If a currency has to be rendered */
	style ^currency {
		extends defaultrow 
		formatter money_euro
	}
		
	/** If a date with weekday has to be rendered */
	style ^date {
		extends defaultrow
		formatter shortdate
	}
		
	/** A pure integer value */
	style integer {
		extends defaultrow
		formatter integer
	}

	/** 1. footer grouping level */
	style grouping_1_foot {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor grau_235
		border-top solid 1 schwarz
		border-bottom solid 1 schwarz
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** 2. and more footer grouping levels */
	style grouping_2_foot {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor grey_250
		border-top solid 1 grey_136
		border-bottom solid 1 grey_136
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}

	/** Table bottom */
	style table_bottom {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor white
		border-top solid 1 black
		border-bottom solid 1 black
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** Footer */
	style footer {
		extends bootstrap
		font arial_7pt_bold
	}
}

pagetemplate A4_Landscape {
	type a4
	orientation landscape
	topmargin 11.5 
	leftmargin 12 
	bottommargin 13 
	rightmargin 14 
	header {
		// showOnFirst
		height 0.6 
		label "a A4 landscape page"
	}
	footer {
		showOnLast
		height 10 
		grid {
			row {
				cell {label "empty"}
			}
			row {
				cell {label "page"}
				cell {autotext page-number}
				cell {label "of"}
				cell {autotext total-page}
				cell {label "end of the page"}
			}
		}
	}
}

report EmployeeSalaryViaFile {
	/** datamart Employee Salary */
	datamart EmployeeSalary
	/** rendering as HTML, PDF also available */
	rendering html
	pagetemplate A4_Landscape
	media small
	/** use the rpt design file */
	file "rptdesign/CCReportFile.rptdesign"
}

report EmployeeSalaryViaTable {
	/** datamart Employee Salary */
	datamart EmployeeSalary
	/** rendering as HTML, PDF also available */
	rendering html
	pagetemplate A4_Landscape
	media small
	/** use table template*/
	template {
		header {
table style bootstrap {
	detailheader style grouping_1_head
	group byEducationLevel by education_level {
		header style grouping_1_head {
			row {
				cell columnspan 7 {property education_level}
			}
		}
		footer style grouping_1_foot { row {} }
	}
	group byPositionTitle by position_title {
		header style grouping_2_head {
			row {
				cell {}
			      cell {property position_title}
			}
		}
		detailheader style grouping_2_head 
		footer style grouping_2_foot {
			row {
		       	cell columnspan 4 {label "sum"}
		            cell {aggregate count style integer}
		            cell {}
		      }
			row {
		      	cell columnspan 5 {label "average"}
		            cell {aggregate average of min_scale style ^currency}
		            cell {aggregate average of salary style ^currency}
		            cell {aggregate average of max_scale style ^currency}
			}
		      row style defaultrow { cell {} }
		}
	}
	details style defaultrow {
		property full_name
		property gender lookups hidelabel {
			string "M" icon "gender_male"
			string "F" icon "gender_female"
		}
		property marital_status lookups hidelabel {
			string "M" icon "marital_married"
			string "S" icon "marital_single"
		}
		property min_scale style ^currency
		property salary style ^currency intervals {
			up to 2000 textcolor red
			up to 2500 cellcolor orange
			up to 2500 textcolor darkblue
			up to 3000 cellcolor white
			up to 100000 cellcolor black
			up to 100000 textcolor lightblue
		}
		property max_scale style ^currency
		property hire_date style ^date
	}
}}

report PlainText {
	datamart EmployeeSalary
	rendering html
	/** an optional external Css URI */
	externalCssURI "css/html/osbp-birt.css" from bundle "My1AppReportDSLPlugin"
	pagetemplate A4_Portrait
	media big 		
	template {
		detail {
			title "it's not me"
			label "with the logo via url..."
			image size-to-image url "http://www.compex-commerce.com/export/system/modules/de.compex.internet/resources/img/logo/logo_compex-commerce.gif"
			label "and what about the logo embedded?"
			image size-to-image embed "C:/plugin/de.compex.utils/img/osbpdesign/compexlogo.png"
			subtitle "sub title #1"
			label "it's me again, but hopefully running, and modified too :/"
			subtitle "sub title #2"
			label "this label has more to say or what?.."
			text "a text will be used to display some data!"
		}
		footer {
			showOnLast
			height 20 mm
			label "there is no page number here, sorry!"
		}
	}
}