Report DSL

From OS.bee documentation
Revision as of 12:29, 1 September 2017 by Dominguez (Talk | contribs) (→‎Report)

Jump to: navigation, search


Documentation

Introduction

Vaadin

Vaadin is a web application framework for Java. In contrast to Javascript libraries and browser-plugin based solutions, Vaadin features a complete stack that includes a robust server-side programming model as well as client-side development tools based on GWT and HTML5.

More information:

https://vaadin.com/home

Birt Report

The Business Intelligence and Reporting Tools (BIRT) Project is an open source software project that provides reporting and business intelligence capabilities for rich client and web applications, especially those based on Java and Java EE. BIRT is a top-level software project within the Eclipse Foundation, an independent not-for-profit consortium of software industry vendors and an open source community.

The project's stated goals are to address a wide range of reporting needs within a typical application, ranging from operational or enterprise reporting to multi-dimensional online analytical processing (OLAP). Initially, the project has focused on and delivered capabilities that allow application developers to easily design and integrate reports into applications. The project is supported by an active community of users at BIRT Developer Center and developers at the Eclipse.org BIRT Project page.

BIRT has two main components: a visual report designer within the Eclipse IDE for creating BIRT Reports, and a runtime component for generating reports that can be deployed to any Java environment. The BIRT project also includes a charting engine that is both fully integrated into the report designer and can be used standalone to integrate charts into an application.

BIRT Report designs are persisted as XML and can access a number of different data sources including JDO datastores, JFire Scripting Objects, POJOs, SQL databases, Web Services and XML.

https://en.wikipedia.org/wiki/BIRT_Project

http://developer.actuate.com/about/

Report DSL

ReportDSL generates the vaddin s ui and birt report.

The main semantic elements of the ReportDSL are:

  • “import” declarations – used to import external models or even Java classes.
  • “package” – the root element that contains all the other elements. A model can contain multiple packages.
  • “layout-data” – the container element that contains all the following layout elements.
    • “externalCssURI” – define the optional external CSS URI for all reports.
    • “formatters” – define the formatter types for all report.
    • “colors” – define the color types for all report.
    • “fonts” – define the font types for all report.
    • “medias” – define the media types for all report.
    • “styles” – define the style types for all report.
    • “pagetemplate” – define the report page template, e.g. page size, orientation, margin, header, footer, etc.
  • “report” – define the data source details for the report, e.g. row/column configurations, legend details and tooltips configurations.

Syntax

All the syntax definitions in this document are described according to the following rules:

  • Definitions in this brackets "<...>" are placeholder.
  • Definitions in this brackets "[...]" are optional.
  • Definitions ending with "*" means they are 0 to n available.
  • "|" between definitions shows different parallel alternatives.
Report DSL instance definition

► Syntax: 

[import <import models/class name>]
package <package name>  {
   ...
   [layout-data {
       [externalCssURI <URIString> [from bundle <BundleString>]]
       colors {...}
       formatters {...}
       fonts {...}
       medias {...}
       styles {...}
       [pagetemplate <PagetemplateID> {    	
       ...
       }]
   ...
   }]
	
   [report <ReportID> {    	
   ...
   }]
...
}

Notes:

  • externalCssURI is used to define the external CSS for all reports in this package.
  • User can also define different formatters, colors, fonts, medias and styles template for all reports in this package. All these definitions could be defined in a separated package and import to other report-packages as well.
  • pagetemplate is used to define the page template format for all reports in this package.
  • For each report definition, a <reportname>+Report.java file will be generated, in which a java class named <reportname>+Report extended from java class CCBaseReport is defined. In this class, report and report configurations are defined. Additionally a <reportname>.rptdesign file will be also gererated, in which a birt report is defined.
Figure 1 - Example birt report layout
Formatters

Formatters is used to define the report format in detail, it is defined as following:

► Syntax: 

formatters {
    <FormatType>
}

FormatType: <UomoFormat> | <NumberFormat> | <CurrencyFormat> | <DateFormat> | <DateTimeFormat> | <TimeFormat>

Notes:

  • The defined formatters are usually used in the definition for styles.
UomoFormat:	uomo <UomoID> {
		    ui "<UiPattern>" report "<ReportPattern>" textalign <TextAlign> 
		}

NumberFormat:	number <NumberID> { 
		    ui "<UiPattern>" report <NumberFormatCategory> "<ReportPattern>" textalign <TextAlign> 
		}

CurrencyFormat:	currency <CurrencyID> { 
		    ui "<UiPattern>" report <CurrencyFormatCategory> "<ReportPattern>" textalign <TextAlign> 
		}

DateFormat:	date <DateID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

DateTimeFormat:	date+time <DateAndTimeID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

TimeFormat:	time <TimeID> { 
		    ui "<UiPattern>" report custom "<ReportPattern>" textalign <TextAlign> 
		}

UomoID: The identification name for the defined uomo format type.
NumberID: The identification name for the number format type.
CurrencyID: The identification name for the currency format type.
DateID: The identification name for the date format type.
DateAndTimeID: The identification name for the date and time format type.
TimeID: The identification name for the time format type.
UiPattern: A text that will be used as pattern for the visualization of the report (actually not used). 
ReportPattern: A text that will be used as format pattern for the corresponding style within the report. 
TextAlign: left | center | right
NumberFormatCategory: unformatted | general-number | fixed | percent | scientific | custom
CurrencyFormatCategory: unformatted | currency | custom

Notes:

  • ui and report defines the layout format in ui and report.
  • textalign defines the text align definition on page.

► Example: 

formatters {
	/** empty UOMO format */
	uomo uomo_test {
		ui "test"
		report "test"
		textalign left
	}
		
	/** money in EURO, rounding half-up */
	currency money_euro {
		ui "###,##0.00 �"
		report currency "#,##0.00 EUR{RoundingMode=HALF_UP}"
		textalign right
	}
		
	/** date without time with weekday */
	date+time shortdate {
		ui "SHORTDATE"
		report custom "dd.MM.yyyy"
		textalign left
	}
		
	/** integer */
	number integer {
		ui "##0"
		report percent "##0"
		textalign right
	}
		
	/** percent */
	number ^percent {
		ui "##0.0'%'"
		report percent "##0.0'%'"
		textalign right
	}
}

styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor schwarz
		backgroundcolor weiss
		font arial_8pt_regular
		media big {
			font arial_12pt_regular
		}
	}
	/** Standardzeile (unterste Ebene) */
	style defaultrow {
		extends bootstrap
		font arial_8pt_regular
		backgroundcolor weiss alternate hellblau
		padding-left 2 pt
		padding-right 2 pt
		media big {
			font arial_12pt_regular
		}
	}
	/** if a currency has to be rendered */
	style ^currency {
		extends defaultrow 
		formatter money_euro
	}
}
Colors

Colors is used to define the report colors in detail, it is defined as following:

► Syntax: 

colors {
  [color <ColorID> ["<ColorString>" | <Darkens> | <Lightens> | <Transforms>]]*
}

ColorID: The identification name of the defined color.
ColorString: The hexadecimal color code.

Darkens: darkens <RefColorID> by-percent <Number>
Lightens: lightens <RefColorID> by-percent <Number>
Transforms: transforms <RefColorID> by-percent <Number> towards <RefColorID>

RefColorID: The reference to the previously defined color via its identification name.
Number: A number to define the value in percentage for darkens, lightens and transforms.

Notes:

  • The defined colors are usually used in the definition for styles.
  • color is defined with the RGB string.
  • darkens, lightens, and transforms could be used to defined the different color darkness of existed color type.

► Example: 

colors {
	/** the basic text color: BLACK */
	color black "#000000"
	/** grey rgb(128,128,128) */
	color grey_128 "#808080"
	/** grey rgb(136,136,136) */
	color grey_136 "#888888"
	/** grey rgb(220,220,220) */
	color grey_220 "#dcdcdc"
	/** grey rgb(235,235,235) */
	color grey_235 "#ebebeb"
	/** grey rgb(250,250,250) */
	color grey_250 "#fafafa"
	/** white */
	color white "#ffffff"
	/** light grey, according to the style guide rather rgb(244,252,255) but it is to weak on screen! */
	color lightgrey "#e4ecff"
	color red "#ff3b30"
	color orange "#ffcc00"
	color darkblue "#007aff"
	color white darkens grey_136 by-percent 50
	color lightblack lightens black by-percent 30 
	color lightblue "#52edc7"
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
		media big {
			font arial_12pt_regular
		}
	}
}
Fonts

Fonts is used to define the report fonts in detail, it is defined as following:

► Syntax: 

fonts {
   [font <FontID> {
      [extends <RefFontID>] [family <BuildInFontFamily> | "<CustomFontFamilyString>"] [<FontStyle>] [bold] [size <UnsignedSizeNumber> <Unit>]
   }]
}

FontID: The identification name for the defined font.
RefFontID: The reference to the previously defined font via its identification name.
BuildInFontFamily: monospace | sans-serif | serif
CustomFontFamilyString: A free available text that should be equal to an existing font family.
FontStyle: normal | italic | oblique
UnsignedSizeNumber: An unsigned number to define the the corresponding font size.
Unit: mm | cm | pt | inch | pc | em | ex | px | %

Notes:

  • The defined fonts are usually used in the definition for styles.
  • New font could be defined based on existed font type using extends.
  • family is used to define type of font and if it is monospace or sans-serif or serif.
  • If it is normal or italic or oblique or bold could be also defined directly.
  • size is used to define the font size.

► Example: 

fonts {
	font arial_14pt_bold {
		family "Arial"
		bold
		size 14 pt
	}
		
	font arial_12pt_regular {
		family "Arial"
		normal
		size 12 pt
	}
		
	font arial_12pt_bold {
		family "Arial"
		bold
		size 12 pt
	}

	font arial_8pt_regular {
		family "Arial"
		normal
		size 8 pt
	}
			
	font arial_7pt_bold {
		family "Arial"
		bold
		size 7 pt
	}
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor schwarz
		backgroundcolor weiss
		font arial_8pt_regular
		media big {
			font arial_12pt_regular
		}
	}
}
Medias

Medias is used to define different report media categories which were used in the style definitions (further documented) to define individual media styles overriding the base style.
It is defined as following:

► Syntax: 

medias {
	[media <MediaID>]*
}

MediaID: The identification name of the defined media.


► Example: 

medias {
	/** Format for tabular reports e.g. for the use at the office */
	media middle
	/** Format for tabular reports e.g. for the use at the warehouse */
	media big
	/** Format for tabular reports e.g. for the use at the office and for the storage */
	media small
	/** Format for tabular reports as invoices, delivery orders, etc. */
	media ^report
}
styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
		media big {font arial_12pt_regular}
	}
		
	/** header */
	style headerarea {
		extends bootstrap
		font arial_10pt_regular
		media big {font arial_12pt_regular}
		media small {font arial_8pt_regular}
	}
}
Styles

Styles is used to define the report styles in detail. The incorporated media style is an individual overriding style for the corresponding mentioned media.
It is defined as following:

► Syntax: 

styles {
	[style <StyleID> {
		[extends <RefStyleID>]
		[formatter <RefFormatterID>]
		[font <RefFontID>]
		[backgroundcolor <RefColorID> [alternate <RefColorID>]]
		[textcolor <RefColorID>]
		[textalign <TextAlign>]
		[border-top <BorderStyle>]
		[border-bottom <BorderStyle>]
		[border-left <BorderStyle>]
		[border-right <BorderStyle>]
		[padding-top <UnsignedNumber> <Unit>]
		[padding-bottom <UnsignedNumber> <Unit>]
		[padding-left <UnsignedNumber> <Unit>]
		[padding-right <UnsignedNumber> <Unit>]
		[margin-top <UnsignedNumber> <Unit>]
		[margin-bottom <UnsignedNumber> <Unit>]
		[margin-left <UnsignedNumber> <Unit>]
		[margin-right <UnsignedNumber> <Unit>]
		[media <RefMediaID> {
			[formatter <RefFormatterID>]
			[font <RefFontID>]
			[backgroundcolor <RefColorID> [alternate <RefColorID>]]
			[textcolor <RefColorID>]
			[textalign <TextAlign>]
			[border-top <BorderStyle>]
			[border-bottom <BorderStyle>]
			[border-left <BorderStyle>]
			[border-right <BorderStyle>]
			[padding-top <UnsignedNumber> <Unit>]
			[padding-bottom <UnsignedNumber> <Unit>]
			[padding-left <UnsignedNumber> <Unit>]
			[padding-right <UnsignedNumber> <Unit>]
			[margin-top <UnsignedNumber> <Unit>]
			[margin-bottom <UnsignedNumber> <Unit>]
			[margin-left <UnsignedNumber> <Unit>]
			[margin-right <UnsignedNumber> <Unit>]
		}]
	}]
}

StyleID: The identification name for the defined style.
RefStyleID: The reference to the previously defined style via its identification name.
RefFormatterID: The reference to the previously defined formatter via its identification name.
RefFontID: The reference to the previously defined font via its identification name.
RefColorID: The reference to the previously defined color via its identification name.
TextAlign: left | center | right

BorderStyle: <BorderType> <WidthNumber> <Unit> <RefColorID>

BorderType: none | solid | dotted | dashed | double | groove | ridge | inset | outset
WidthNumber: Unsigned number to define the corresponding border width.
Unit: mm | cm | pt | inch | pc | em | ex | px | %

UnsignedNumber: Unsigned number to define the corresponding top, bottom, left and right padding or margin.

Notes:

  • New style could be defined based on existed style type using extends.
  • formatter, font, backgroundcolor, textcolor could be defined using existed definitions.
  • Textalign, border details, padding details and margin details could be also defined in detail.
  • Formatter, font, color, textalign, border details, padding details and margin details are redefinedable for existed media.


► Example: 

styles {
	/** Bootstrap style */
	style bootstrap {
		textcolor black
		backgroundcolor white
		font arial_8pt_regular
		media big {
			font arial_12pt_regular
		}
	}
		
	/** Headline */
	style headline {
		extends bootstrap
		font arial_14pt_bold
	}
		
	/** Header */
	style headerarea {
		extends bootstrap
		font arial_10pt_regular
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** Table header */
	style tableheader {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_220
		border-top solid 1 pt black
		border-bottom solid 1 pt black
		border-left solid 1 pt grey_128
		border-right solid 1 pt grey_128
		media big {
			font arial_12pt_bold
		}
	}

	/** 1. header grouping level */
	style grouping_1_head {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_235
		border-top solid 1 pt black
		border-bottom solid 1 pt grey_136
		media big {
			font arial_12pt_bold
		}
		media small {
			font arial_8pt_bold
		}
	}

	/** 2. and more header grouping levels */
	style grouping_2_head {
		extends bootstrap
		font arial_10pt_bold
		backgroundcolor grey_250
		border-top solid 1 pt grey_136
		media big {
			font arial_12pt_bold
		}
		media small {
			font arial_8pt_bold
		}
	}
		
	/** Standard line (lowest level) */
	style defaultrow {
		extends bootstrap
		font arial_8pt_regular
		backgroundcolor white alternate lightblue
		padding-left 2 pt
		padding-right 2 pt
		media big {
			font arial_12pt_regular
		}
	}
		
	/** If a currency has to be rendered */
	style ^currency {
		extends defaultrow 
		formatter money_euro
	}
		
	/** If a date with weekday has to be rendered */
	style ^date {
		extends defaultrow
		formatter shortdate
	}
		
	/** A pure integer value */
	style integer {
		extends defaultrow
		formatter integer
	}

	/** 1. footer grouping level */
	style grouping_1_foot {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor grau_235
		border-top solid 1 pt schwarz
		border-bottom solid 1 pt schwarz
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** 2. and more footer grouping levels */
	style grouping_2_foot {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor grey_250
		border-top solid 1 pt grey_136
		border-bottom solid 1 pt grey_136
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}

	/** Table bottom */
	style table_bottom {
		extends bootstrap
		font arial_10pt_regular
		backgroundcolor white
		border-top solid 1 pt black
		border-bottom solid 1 pt black
		media big {
			font arial_12pt_regular
		}
		media small {
			font arial_8pt_regular
		}
	}
		
	/** Footer */
	style footer {
		extends bootstrap
		font arial_7pt_bold
	}
}
Pagetemplate

Pagetemplete is used to define the basic format for different page layouts, it is defined as following:
Notes:

  • type is used to define the page size, e.g. a4, a3, ect.
  • orientation is used to define the page orientation, e.g. portrait or landscape.
  • topmargin, leftmargin, bottommargin and rightmargin are used to define the margin size.
  • header and footer are used to define the header and footer details, e.g.: height, if it will be show on first, etc.

► Syntax:

pagetemplate <PageTemplateID>{

    type <PageSize>
    orientation <Orientation>
    topmargin <UnsignedNumber> <Unit>
    leftmargin <UnsignedNumber> <Unit>
    bottommargin <UnsignedNumber> <Unit>
    rightmargin <UnsignedNumber> <Unit>
    [header {
       [showOnFirst]
       height <UnsignedNumber> <Unit>
       <#Element>
    }]
    [footer {
       [showOnLast]
       height <UnsignedNumber> <Unit>
       <#Element>
    }]
}


PageTemplateID: The identification name for the defined page template.
PageSize: a4 | a3 | a5 | us-letter | us-legal | us-ledger | us-super-b
Orientation: portrait | landscape
UnsignedNumber: Unsigned number to define the top, left, bottom or right margin and the header or footer height.
Unit: mm | cm | pt | inch | pc | em | ex | px | %

Element:
 <#Title> | <#SubTitle> | <#SubSubTitle> | <#Label> | <#Text> | <#AutoText> | <#Image> | <#DatamartTable> | <#DatamartTableAttribute> | <#Grid>


Title:
  title "<TitleText>" [style <RefStyleID>]

TitleText: A text used for the title element.
RefStyleID: A selected style reference of the previously defined styles via its identification name.


SubTitle:
  subtitle "<SubTitleText>" [style <RefStyleID>]

SubTitleText: A text used for the subtitle element.
RefStyleID: The reference to the previously defined style via its identification name.


SubSubTitle:
  subsubtitle "<SubSubTitleText>" [style <RefStyleID>]

SubSubTitleText: A text used for the subsubtitle element.
RefStyleID: The reference to the previously defined style via its identification name.


Label:
   label "<LabelText>" [style <RefStyleID>]

LabelText: A text used for the label element.
RefStyleID: The reference to the previously defined style via its identification name.


Text:
   text "<Text>" [style <RefStyleID>]

Text: A text used for the text element.
RefStyleID: The reference to the previously defined style via its identification name.


AutoText:
   autotext <AutoTextType> [style <RefStyleID>]

AutoTextType: page-number | total-page | page-number-unfiltered | total-page-unfiltered | page-variable
RefStyleID: The reference to the previously defined style via its identification name.


Grid:
   grid [as <GridID>] { <#GridRow>* }

GridID: The identification name for the defined grid.


GridRow:
   row [as <GridRowID>] [style <RefStyleID>] { <#GridCell>* }

GridRowID: The identification name for the defined grid row.
RefStyleID: The reference to the previously defined style via its identification name.


GridCell:
   cell [as <GridCellID>] [columnspan <Integer>] { <#Element>* }

GridCellID: The identification name for the defined grid cell.


DatamartTable:
   table [style <RefStyleID>] {

      [detailheader [style <RefStyleID>]]
      [detailfooter [style <RefStyleID>]]
      <#DatamartTableGroup>*
      <#DatamartTableDetail>
  }

RefStyleID: The reference to the previously defined style via its identification name.


DatamartTableGroup:
   group <GroupID> by <RefDatamartAttributeID> {

      [<#DatamartTableGroupHeader>]
      [[detailheader] [style <RefStyleID>]]
      [[detailfooter] [style <RefStyleID>]]
      [<#DatamartTableGroupFooter>]
  }

RefStyleID: The reference to the previously defined style via its identification name.


DatamartTableGroupHeader:
   header [style <RefStyleID>] { <#GridRow>* }

RefStyleID: The reference to the previously defined style via its identification name.


DatamartTableGroupFooter:
   footer [style <RefStyleID>] { <#GridRow>* }

RefStyleID: The reference to the previously defined style via its identification name.


DatamartTableDetail:
   details [style <RefStyleID>] [all | [{ <#DatamartTableAttribute>* }]]

RefStyleID: The reference to the previously defined style via its identification name.


DatamartTableAttribute:
   <TableValueElement> [style <RefStyleID>]

      [image <#TableImage>]
      [intervals [hidelabel] { <TableInterval>* }]
      [lookups [hidelabel] { <TableLookup>* }]

TableValueElement: #TableAttribute | #TableAggregation
RefStyleID: The reference to the previously defined style via its identification name.
TableInterval: #TableNumberInterval | #TableDateDayInterval
TableLookup: #TableNumberLookup | #TableStringLookup | #TableDateDayLookup.


TableAttribute:
   attribute <RefDatamartAttributeID>

RefDatamartAttributeID: The reference to the previously in the DatamartDSL defined datamart attribute via its identification name.


TableAggregation:
   aggregate <TableBaseAggregation> [on-group <RefDatamartTableGroupID>] [title "<TitelText>"]

TableBaseAggregation: #TablePureAggregation | #TableUnaryAggregation | #TableMultipleAggregation | #TableBinaryAggregation.
RefDatamartTableGroupID: The reference to the previously defined datamart table group via its identification name.
TitelText: The title text as String.


TableImage:
   path "<ImagePathPattern>" [dynamic] [hidelabel] [resize] ["<ResizeString>"]

ImagePathPattern: XXXX.
ResizeString: XXXX.


TablePureAggregation:
   count | running-countpath


TableUnaryAggregation:
   sum | average | minimum | maximum | running-sum of <RefDatamartAttributeID>*

RefDatamartAttributeID: The reference to the previously in the DatamartDSL defined datamart attribute via its identification name.


TableMultipleAggregation:
   concat of <RefDatamartAttributeID>*

RefDatamartAttributeID: The reference to the previously in the DatamartDSL defined datamart attribute via its identification name.


TableBinaryAggregation:
   divide of <RefDatamartAttributeID>*

RefDatamartAttributeID: The reference to the previously in the DatamartDSL defined datamart attribute via its identification name.


TableNumberInterval:
   upTo <SignedNumber> <#TableRangeElement>

SignedNumber: A signed number to define the number interval.


TableNumberLookup:
   number <SignedNumber> <#TableRangeElement>

SignedNumber: A signed number to define the number lookup.


TableStringLookup:
   string "<String>" <#TableRangeElement>

String: XXXXXXXXXXXXXXXX string lookup.


TableDateDayLookup:
   daysInPast <SignedNumber> "<#TableRangeElement>

SignedNumber: A signed number to define the days in past.


TableRangeElement:
   textcolor <RefColorID> | cellcolor <RefColorID> | icon "<IconString>" | trend <TrendIcon>

RefColorID: The reference to the previously defined color via its identification name.
IconString: XXXX.
TrendIcon: rising | bad-rising | sloping | good-sloping | stagnating.

► Example: 

pagetemplate A4_Landscape {
	type a4
	orientation landscape
	topmargin 11.5 mm
	leftmargin 12 mm
	bottommargin 13 mm
	rightmargin 14 mm
	header {
		// showOnFirst
		height 0.6 inch
		label "a A4 landscape page"
	}
	footer {
		showOnLast
		height 10 mm
		grid {
			row {
				cell {label "empty"}
			}
			row {
				cell {label "page"}
				cell {autotext page-number}
				cell {label "of"
				cell {autotext total-page}
				cell {label "end of the page"
			}
		}
	}
}
Report

► Syntax:

report <reportName> [described by "<descriptionValue>"] [toolbar <RefActionToolbar>] {

    dataMart <datamartDefinition> rendering <renderingOption> [externalCssURI "<externalCssURI>" [from bundle "<externalCssURIBundle>"]]
    pagetemplate <RefPageTemplate> media <RefMedia>
    <reportDesign>
}


reportName: A defined identification name for the report.
descriptionValue: A description text used in the automated documentation via MDD (model driven documentation).
RefActionToolbar: A selected toolbar reference from the previously defined action toolbars in an ActionDSL model via its identification name.
RefDatamartDefinition: A selected datamart reference from the previously defined datamart definitions in an DatamartDSL model via its identification name.
renderingOption: html | pdf
externalCssURI: The definition of the Uniform Resource Identifier (URI) of an external CSS for this specific report.
externalCssURIBundle: The bundle where to search the external CSS.
RefPageTemplate: A selected page template reference from the previously defined templates in the layout-data as described above via its identification name.
RefMedia: A selected media reference from the previously defined medias in the layout-data as described above via its identification name.

Notes:

  • For <page size> are the following options available: 'a4', 'a3', 'a5', 'us-letter', 'us-legal', "us-ledger" or "us-super-b".
  • For <orientation> are the following options available: 'portrait' or 'landscape'.
  • For <unsigned number> use an usable unsigned number.
  • For <unit> are the following options available: 'mm', 'cm', 'pt', 'inch', 'pc', 'em', 'ex', 'px', '%'.
  • title, subtitle, subsubtitle, label text, autotext, image, datamarttable, datamarttableproperty and grid could be defined detailed using/ not using existed style template in this element.
  • All details of report are defined in xx.rptdesign file according to birt report syntax and semantics.

► Example: 

title "Employee Salary" style headerarea
datamarttable EmployeeSalary as salaryGrouped style bootstrap {
	detailheader style grouping_1_head
	group byEducationLevel by education_level {
		header style grouping_1_head {
			row {
				cell columnspan 7 {property education_level}
			}
		}
		footer style grouping_1_foot { row {} }
	}
	group byPositionTitle by position_title {
		header style grouping_2_head {
			row {
				cell {}
			      cell {property position_title}
			}
		}
		detailheader style grouping_2_head 
		footer style grouping_2_foot {
			row {
		       	cell columnspan 4 {label "sum"}
		            cell {aggregate count style integer}
		            cell {}
		      }
			row {
		      	cell columnspan 5 {label "average"}
		            cell {aggregate average of min_scale style ^currency}
		            cell {aggregate average of salary style ^currency}
		            cell {aggregate average of max_scale style ^currency}
			}
		      row style defaultrow { cell {} }
		}
	}
	details style defaultrow {
		property full_name
		property gender lookups hidelabel {
			string "M" icon "gender_male"
			string "F" icon "gender_female"
		}
		property marital_status lookups hidelabel {
			string "M" icon "marital_married"
			string "S" icon "marital_single"
		}
		property min_scale style ^currency
		property salary style ^currency intervals {
			up to 2000 textcolor red
			up to 2500 cellcolor orange
			up to 2500 textcolor darkblue
			up to 3000 cellcolor white
			up to 100000 cellcolor black
			up to 100000 textcolor lightblue
		}
		property max_scale style ^currency
		property hire_date style ^date
	}
}
Report

Formatters is used to define the report format in detail, it is defined as following:

► Syntax: 

report <report name> [described by <discription>] {
[datamart <datamart name>]
	rendering RenderingEnum
	[externalCssURI <Css URI string> [from bundle <bundle string>] ]
	pagetemplate <existed PageTemplate ID>
media <existed Media ID>
	file <file name>
| template {
		[described by <discription>]
 		[header {
			[showOnLast]
			height <height number> UnitEnum
			CCElement
}]
   		detail { CCElement }
    		[footer {
			[showOnLast]
			height <height number> UnitEnum
			CCElement
}]
}
}

UnitEnum: mm | cm | pt | inch | pc | em | ex | px | %
RenderingEnum: html | pdf

Notes:

  • Generate a <reportname>+Report.java file, in which a java class named <reportname>+Report extended from java class CCBaseReport is defined. In this class, report and report configurations are defined.
  • Generate a <reportname>.rptdesign file, in which a birt report is defined.
  • rendering is used to define the output format of report, e.g.: HTML or PDF.
  • If the existed report should be used, it could be defined with keyword file with path+filename string.
  • template is used to define the header, footer and all other specifically detail for the report.

► Example: 

report EmployeeSalaryViaFile {
	/** datamart Employee Salary */
	datamart EmployeeSalary
	/** rendering als HTML, auch PDF möglich */
	rendering html
	pagetemplate A4_Landscape
	media small
	/** das rptDesign verwenden */
	file "rptdesign/CCReportFile.rptdesign"
}

report PlainText {
	datamart EmployeeSalary
	rendering html
	/** an optional external Css URI */
	externalCssURI "css/html/ccng-birt2.css" from bundle "FoodMartReportDSLPlugin2"
	pagetemplate A4_Portrait
	media big 		
	template {
		detail {
			title "it's not me"
			label "with the logo via url..."
			image size-to-image url "http://www.compex-commerce.com/export/system/modules/de.compex.internet/resources/img/logo/logo_compex-commerce.gif"
			label "now the logo via file..."
			image size-to-image file "platform:/plugin/de.compex.utils/img/ccngdesign/compexlogo.png"
			label "and what about the logo embedded?"
			image size-to-image embed "platform:/plugin/de.compex.utils/img/ccngdesign/compexlogo.png"
			subtitle "sub title #1"
			label "it's me again, but hopefully running, and modified too :/"
			subtitle "sub title #2"
			label "this label has more to say or what?.."
			text "a text will be used to display some data!"
		}
		footer {
			showOnLast
			height 20 mm
			label "there is no page number here, sorry!"
		}
	}
}

Copyright Notice

All rights are reserved by Compex Systemhaus GmbH. In particular, duplications, translations, microfilming, saving and processing in electronic systems are protected by copyright. Use of this manual is only authorized with the permission of Compex Systemhaus GmbH. Infringements of the law shall be punished in accordance with civil and penal laws. We have taken utmost care in putting together texts and images. Nevertheless, the possibility of errors cannot be completely ruled out. The Figures and information in this manual are only given as approximations unless expressly indicated as binding. Amendments to the manual due to amendments to the standard software remain reserved. Please note that the latest amendments to the manual can be accessed through our helpdesk at any time. The contractually agreed regulations of the licensing and maintenance of the standard software shall apply with regard to liability for any errors in the documentation. Guarantees, particularly guarantees of quality or durability can only be assumed for the manual insofar as its quality or durability are expressly stipulated as guaranteed. If you would like to make a suggestion, the Compex Team would be very pleased to hear from you.

(c) 2016-2024 Compex Systemhaus GmbH

Retrieved from "https://download.osbee.org/documentation/index.php?title=Report_DSL&oldid=2217"